Don't insert duplicate imports

Wilfred · Wilfred · commit e2f6d2cf5a67 · 2017-01-17T12:02:16.000Z
diff --git a/pyimport.el b/pyimport.el
@@ -79,6 +79,24 @@ To terminate the loop early, throw 'break."
          (string= keyword2 "from")
          (string= mod1 mod2))))
 
+(defun pyimport--insert-from-symbol (symbol)
+  "When point is a on an import line, add SYMBOL."
+  ;; Assumes the current line is of the form 'from foo import bar, baz'.
+
+  ;; Step past the 'from '.
+  (goto-char (line-beginning-position))
+  (while (not (looking-at "import "))
+    (forward-char 1))
+  (forward-char (length "import "))
+
+  (insert
+   (->> (delete-and-extract-region (point) (line-end-position))
+        (s-split ", ")
+        (cons symbol)
+        (-sort #'string<)
+        (-uniq)
+        (s-join ", "))))
+
 (defun pyimport--insert-import (line)
   "Insert LINE, a python import statement, in the current buffer."
   (let* ((current-lines (pyimport--import-lines (current-buffer)))
@@ -87,9 +105,8 @@ To terminate the loop early, throw 'break."
         ;; Find the first matching line, and append there
         (pyimport--for-each-line
           (when (pyimport--same-module (pyimport--current-line) line)
-            (goto-char (point-at-eol))
             (-let [(_ _module _ name) (s-split " " line)]
-              (insert ", " name))
+              (pyimport--insert-from-symbol name))
             ;; Break from this loop.
             (throw 'break nil)))
 
diff --git a/test/pyimport-test.el b/test/pyimport-test.el
@@ -117,3 +117,29 @@
     (setq result-lines (nreverse result-lines))
     (should
      (equal result-lines '("a" "b" "c" "d")))))
+
+(ert-deftest insert-import-simple ()
+  "Test inserting an import."
+  (with-temp-buffer
+    (pyimport--insert-import "from foo import x")
+    (should
+     (equal (buffer-string)
+            "from foo import x\n"))))
+
+(ert-deftest insert-import-with-existing ()
+  "Test inserting an import when we already have imports from that module."
+  (with-temp-buffer
+    (insert "from foo import x\n")
+    (pyimport--insert-import "from foo import y")
+    (should
+     (equal (buffer-string)
+            "from foo import x, y\n"))))
+
+(ert-deftest insert-import-duplicate ()
+  "Test inserting an import when we already have that symbol imported"
+  (with-temp-buffer
+    (insert "from foo import x\n")
+    (pyimport--insert-import "from foo import x")
+    (should
+     (equal (buffer-string)
+            "from foo import x\n"))))
